HIBRIDACIÓ sp3

(* FUNCIÓ D'ONA DE L'ÀTOM D'HIDROGEN (a.u.) *)
 Clear["Global`*"];
 rad[n_,l_]:=Sqrt[(2/n)^3*(n-l-1)!/(2*n*((n+l)!))]*
                                            LaguerreL[n-l-1,2*l+1,2*r/n]*(2*r/n)^l*Exp[-r/n];
y[l_,ml_]:= SphericalHarmonicY[l,ml,θ,ϕ];

(* Orbitals 2s, 2px, 2py, 2pz *)

s2=rad[2,0]*y[0,0];
px= rad[2,1]*(y[1,1]-y[1,-1])*(-1/Sqrt[2]);
py=rad[2,1]*(y[1,1]+y[1,-1])*(I/Sqrt[2]);
pz=rad[2,1]*y[1,0];

(* els quatro ORBITALS HÍBRIDS sp3 *)

sp31=(1/2)*(s2+px+py+pz);
 sp32=(1/2)*(s2-px-py+pz);
 sp33=(1/2)*(s2+px-py-pz);
sp34=(1/2)*(s2-px+py-pz);

(* REPRESENTACIONS *)

(* Càlcul del radi de màxima probabilitat *)
f[r_]:=Integrate[sp31^2*r^2*Sin[θ],{θ,0,Pi},{ϕ,0,2*Pi}];
rmax1=FindRoot[D[f[r],r]==0,{r,4}][[1,2]];

(* Càlcul de les superfícies dels hibrids al radi de màxima probabilitat *)
rsp31=sp31/.r->rmax1;
rsp32=sp32/.r->rmax1;
rsp33=sp33/.r->rmax1;
rsp34=sp34/.r->rmax1;

(* Plot les superfícies dels hibrids al radi de màxima probabilitat *)
fig1=SphericalPlot3D[rsp31^2,{θ,0,Pi},{ϕ,0,2*Pi},PlotRange->All];
fig2=SphericalPlot3D[rsp32^2,{θ,0,Pi},{ϕ,0,2*Pi},PlotRange->All];
fig3=SphericalPlot3D[rsp33^2,{θ,0,Pi},{ϕ,0,2*Pi},PlotRange->All];
fig4=SphericalPlot3D[rsp34^2,{θ,0,Pi},{ϕ,0,2*Pi},PlotRange->All];

(* unió de les quatre representacions *)
Show[fig1,fig2,fig3,fig4]